В конфигурациях на базе платформы в 1С:Предприятие 8.3 имеется довольно широкий ассортимент типовых печатных форм, но бывают ситуации, когда необходима разработка уникального печатного документа.
Разработаем печатную форму для документа «Заказ клиента»: заходим в конфигуратор, нажимаем кнопку «Файл-Новый-Внешняя обработка».
Рис.1 Создание внешней обработки
Вводим название печатной формы в поле Имя и Синоним.
Рис.2 Заполнение реквизитов новой печатной формы
Сведения о внешней обработке
В модуле объекта укажем, что вид обработки – печатная форма, что она должна быть прикреплена к Заказу клиента:
Рис.3 Ввод сведений о внешней печатной форме
Функция СведенияОВнешнейОбработке() Экспорт
ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.2.2.1");
ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиПечатнаяФорма();
ПараметрыРегистрации.Версия = "1.1";
ПараметрыРегистрации.Назначение.Добавить("Документ.ЗаказКлиента");
НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
НоваяКоманда.Представление = НСтр("ru = 'Протокол согласования цен'");
НоваяКоманда.Идентификатор = "ПротоколСогласованияЦенЗаказаКлиента";
НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
НоваяКоманда.ПоказыватьОповещение = Истина;
НоваяКоманда.Модификатор = "ПечатьMXL";
Возврат ПараметрыРегистрации;
КонецФункции
Подготовка к печати
Следующим этапом нужно прописать процедуры печати для вызова печати из общих модулей конфигурации.
Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыПечати = Неопределено) Экспорт
УстановитьПривилегированныйРежим(Истина);
Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "ПротоколСогласованияЦенЗаказаКлиента") Тогда
УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "ПротоколСогласованияЦенЗаказаКлиента", НСтр("ru = 'Протокол согласования цен'"),
ПечатьПСЦ(МассивОбъектов, ОбъектыПечати));
КонецЕсли;
КонецПроцедуры
Создание внешней печатной формы
Добавляем новый макет печатной формы к обработке.
Рис.4 Создание макета печатной формы
Рис.5 Выбор типа макета печатной формы
Создаем необходимые строки и столбцы:
Рис.6 Редактирование макета печатной формы
Для вывода данных в параметры печатной формы используем функцию ПечатьПСЦ:
Функция ПечатьПСЦ(МассивОбъектов, ОбъектыПечати)
Макет = ПолучитьМакет("Макет");
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| ЗаказКлиентаТовары.Ссылка.Договор.Номер КАК ДоговорНомер,
| ЗаказКлиентаТовары.Ссылка.Организация.ИНН КАК ОрганизацияУНП,
| ЗаказКлиентаТовары.Цена КАК Цена,
| ЗаказКлиентаТовары.Ссылка.Номер КАК НомерДок,
| ЗаказКлиентаТовары.Ссылка.Дата КАК ДатаДок,
| ЗаказКлиентаТовары.Ссылка.Договор.ДатаОкончанияДействия КАК ДатаОкончанияДоговора,
| ЗаказКлиентаТовары.Ссылка КАК Ссылка
|ИЗ
| Документ.ЗаказКлиента.Товары КАК ЗаказКлиентаТовары
|ГДЕ
| ЗаказКлиентаТовары.Ссылка В(&Объекты)
|ИТОГИ ПО
| Ссылка";
Запрос.УстановитьПараметр("Объекты", МассивОбъектов);
Результат = Запрос.Выполнить();
Если Результат.Пустой() Тогда
Возврат Новый ТабличныйДокумент;
КонецЕсли;
ТабДок = Новый ТабличныйДокумент;
ТабДок.ОриентацияСтраницы = ОриентацияСтраницы.Портрет;
ТабДок.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_ПротоколСогласованияЦен";
ТабДок.ПолеСверху = 0;
ТабДок.ПолеСлева = 0;
ТабДок.ПолеСнизу = 0;
ТабДок.ПолеСправа = 0;
ТабДок.РазмерКолонтитулаСверху = 0;
ТабДок.РазмерКолонтитулаСнизу = 0;
ТабДок.АвтоМасштаб = Истина;
Шапка = Результат.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
Пока Шапка.Следующий() Цикл
Если ТабДок.ВысотаТаблицы > 0 Тогда
ТабДок.ВывестиГоризонтальныйРазделительСтраниц();
КонецЕсли;
НомерСтрокиНачало = ТабДок.ВысотаТаблицы + 1;
ОбластьШапкаТаблицы = Макет.ПолучитьОбласть("ШапкаТаблицы");
ТабДок.Вывести(ОбластьШапкаТаблицы);
Выборка = Шапка.Выбрать();
Пока Выборка.Следующий() Цикл
ОбластьДетальныхЗаписей = Макет.ПолучитьОбласть("Детали");
Если ЗначениеЗаполнено(Выборка.ДоговорНомер) Тогда
ОбластьДетальныхЗаписей.Параметры.НомерПСЦ = СокрЛП(Выборка.ДоговорНомер) + "-" + ПрефиксацияОбъектовКлиентСервер.ПолучитьНомерНаПечать(Выборка.НомерДок, Истина, Истина);
КонецЕсли;
Если ЗначениеЗаполнено(Выборка.ОрганизацияУНП) Тогда
ОбластьДетальныхЗаписей.Параметры.ОрганизацияУНП = Число(Выборка.ОрганизацияУНП);
КонецЕсли;
Если ЗначениеЗаполнено(Выборка.Цена) Тогда
ОбластьДетальныхЗаписей.Параметры.Цена = Выборка.Цена;
КонецЕсли;
Если ЗначениеЗаполнено(Выборка.ДатаДок) Тогда
ОбластьДетальныхЗаписей.Параметры.ДатаДок = Выборка.ДатаДок;
КонецЕсли;
Если ЗначениеЗаполнено(Выборка.ДатаОкончанияДоговора) Тогда
ОбластьДетальныхЗаписей.Параметры.ДатаОкончанияДоговора = Выборка.ДатаОкончанияДоговора;
КонецЕсли;
ТабДок.Вывести(ОбластьДетальныхЗаписей);
КонецЦикла;
УправлениеПечатью.ЗадатьОбластьПечатиДокумента(ТабДок, НомерСтрокиНачало, ОбъектыПечати, Шапка.Ссылка);
КонецЦикла;
Возврат ТабДок;
КонецФункции
Подключение внешней печатной формы
После создания необходимо подключить обработку в рабочую базу. Нужно зайти в раздел «НСИ и Администрирование-Печатные формы, отчеты и обработки».
Рис.7 Добавление печатной формы в базу
Затем нажимаем «Дополнительные отчеты и обработки».
Рис.8 Добавление печатной формы как обработки
В командной панели нажимаем кнопку «Создать».
Рис.9 Загрузка внешней обработки
Программа выдаст окно проводника для выбора внешнего файла обработки. После загрузки файла программа из сведений об обработке подтянет название печатной формы, вид обработки (печатная форма), а также размещение печатной формы в документе «Заказ клиента».
Рис.10 Заполнение реквизитов дополнительной обработки
Новая внешняя печатная форма будет отображаться в печати документа «Заказ клиента», а также в списке заказов.
Рис.11 Печать внешней печатной формы из документа
После открытия печатной формы можно ее вывести на печать.
Рис.12 Печатная форма протокола согласования цен
Самостоятельная разработка печатной формы – выполнимая задача для продвинутого пользователя 1С, и добавление внешней печатной формы в базу также не составит труда. Программа сама определит на основании данных, введенных в коде обработки, что обработка – это печатная форма, и сама поместит печатную форму в нужный объект базы.